;+
; Function to return a default aperture efficiency, given an
; observing frequency.  Used in the calibration routines.
;
; The formula for Q-band comes from the PTCS Project Note 43 
; by Balser, Prestage & Nikolic.  At other frequencies, the value returned 
; is just an educated guess, at this point.
;
; @param freq {in}{required}{type=float} Observing frequency in GHz
; @param elev {in}{optional}{type=float} Observing elevation in degrees
; @examples
; <pre>
;    apeff = get_ap_eff(18.5,45.0)
;    print,apeff
; </pre>
;
; @version $Id: get_ap_eff.pro,v 1.1 2005/02/25 18:19:53 jbraatz Exp $
;-

function get_ap_eff,freq,elev

   compile_opt idl2

   ; Check parameters
   if n_elements(freq) ne 1 then begin
      message,"A frequency must be supplied.",/info
      return, 0
   endif
   if freq gt 115.0 then begin
      message,"Frequency out of range.",/info
      return, 0
   endif
   if n_elements(elev) eq 0 then elev = 51.0
   if elev lt 0.0 or elev gt 90.0 then begin
      message,"Elevation out of range.",/info
      return, 0
   endif

   ; Set the aperture efficiency
   if freq gt 52.0 then $
      ap_eff = 0.25 * exp(-((elev-51.0)/40.0)^2) $
   else if freq gt 40.0 then $
      ap_eff = 0.41 * exp(-((elev-51.0)/52.0)^2) $
   else if freq gt 26.0 then  $
      ap_eff = 0.50 * exp(-((elev-51.0)/60.0)^2) $
   else if freq gt 18.0 then $
      ap_eff = 0.58 * exp(-((elev-51.0)/70.0)^2) $
   else if freq gt 12.0 then $
      ap_eff = 0.65 $
   else $
      ap_eff = 0.71
   return,ap_eff
end