;+
; Specify the SDFITS file from which data will be read.
;
; @param file_name {in}{optional}{type=string} The file name to
; use.  If omitted, a file selector GUI will appear and you can select
; the file to use.  You can not select a directory in that case.  If
; the file_name is a directory, the underlying code will recognize
; that and it will be as if you had used
; <a href="dirin.html">filein</a> instead.
;
; @uses <a href="sdfitsin.html">sdfitsin</a>
;
; @version $Id: filein.pro,v 1.7 2005/05/24 20:58:24 jbraatz Exp $
;-
pro filein, file_name, _EXTRA=ex
    if (!g.line) then begin
        new_io = sdfitsin(file_name, _EXTRA=ex)
        if (obj_valid(new_io)) then begin
            if (obj_valid(!g.lineio)) then obj_destroy, !g.lineio
            !g.lineio = new_io
            !g.line_filein_name = file_name
        endif
    endif else begin
        new_io = sdfitsin(file_name, /continuum, _EXTRA=ex)
        if (obj_valid(new_io)) then begin
            if (obj_valid(!g.contio)) then obj_destroy, !g.contio
            !g.contio = new_io
            !g.cont_filein_name = file_name
        endif
    endelse
end