;+
; Specify the file to which data will be written.
; The filename is stored in the !g.lineoutio field.
;
; The output file name must use the ".fits" suffix.
;
; Note that it is not currently possible to save continuum data.
;
; @param file_name {in}{required}{type=string} The file to which
; data will be written.  If the file does not exist, it will be created after
; the first use of <a href="keep.html">keep</a>
;
; @examples
; <pre>
;    getrec,1
;    show
;    fileout,'savedfile.fits'
;    keep
; </pre>
;
;
; @version $Id: fileout.pro,v 1.6 2005/05/24 21:00:43 jbraatz Exp $
;-
pro fileout, file_name
    if (!g.line) then begin
        if (not stregex(file_name,'.*\.fits$',/boolean)) then begin
            message, 'file_name must be of the form *.fits',/info
            return
        endif
        new_io = obj_new('io_sdfits_writer')
        if (obj_valid(new_io)) then begin
            if (obj_valid(!g.lineoutio)) then obj_destroy, !g.lineoutio
            !g.lineoutio = new_io
            if (!g.lineoutio->file_exists(file_name) eq 1) then begin
                !g.lineoutio->set_file, file_name
                !g.line_fileout_name = file_name
            endif else begin
                if (strpos(file_name,'/') ne -1) then begin
                    !g.lineoutio->set_file_path, file_dirname(file_name)
                    file_base = file_basename(file_name)
                endif else begin
                    file_base = file_name
                endelse
                parts=strsplit(file_base,'.',/extract)
                index_file = strjoin(parts[0:n_elements(parts)-2],'.') + '.index'
                !g.lineoutio->set_index_file_name, index_file
                !g.lineoutio->set_output_file, file_base
                !g.line_fileout_name = file_name
            endelse
        endif
    endif else begin
        message, 'continuum data can not be saved', /info
    endelse
end