;+
; Retrieves data from the output data file and places it in the PDC (!g.s[0]).
; Use the selection parameters to specify which data to retrieve.
;
; See the
; <a href="../toolbox/io/line_index__define.html#_LINE_INDEX::search_index">line search index</a>
; for the full set of parameters that are available.
;
; Only spectral line data can currently be fetched from a keep file.
;
; @uses <a href="set_data_container.html">set_data_container</a>
; @examples
; <pre>
;   getnod,30
;   fileout,'mysave.fits'
;   keep
;   getnod, 32
;   keep
;   kget,index=0   ; retrieves the first record in the keep file
; </pre>
;
; @version $Id: kget.pro,v 1.4 2005/05/25 13:24:05 jbraatz Exp $
;-
pro kget, _EXTRA=ex
   compile_opt idl2

   if (!g.line) then begin
       dc = !g.lineoutio->get_spectra(_EXTRA=ex)

       if (data_valid(dc) gt 0) then begin
           if (n_elements(dc) gt 1) then begin
               message,'More than one item fetched - ignoring all by the first',$
                   /info
               dc = dc[0]
           endif
           set_data_container, dc
           data_free, dc
       endif else begin
           message, 'Fetched data appears to be empty or invalid',/info
       endelse
   endif else begin
       message, 'Continuum data can not be fetched from a keep file, sorry.',/info
   endelse

end