;+
; This procedure scales the data container's data by a scalar value.
;
; Equivalent to:
; *!g.s[0].data_ptr = *!g.s[0].data_ptr * factor
; 
; @param factor {in}{required}{type=float} scale factor
; @param index {in}{optional}{type=int} index to DC to be scaled
;
; @examples
; <pre>
;    get,index=1
;    show
;    scale,1.3
;    show
; </pre>
;
; @uses <a href="../toolbox/dcscale.html">dcscale</a>
;
; @version $Id: scale.pro,v 1.7 2005/05/30 04:03:43 bgarwood Exp $
;-

pro scale,factor,index

    on_error,2

    if n_elements(factor) eq 0 then begin
       message,"you must provide a scaling factor.",/info
       return
    end
    if n_elements(index) eq 0 then index = 0
    if index gt 15 then begin
       message,"illegal index value",/info
       return
    end
    if !g.line then begin
        if (data_valid(!g.s[index]) le 0) then begin
            message,'No data at indicated index',/info
            return
        endif
	dcscale,!g.s[index],factor
    endif else begin    
        if (data_valid(!g.c[index]) le 0) then begin
            message,'No data at indicated index',/info
            return
        endif
	dcscale,!g.c[index],factor
    endelse
    if index eq 0 and !g.frozen eq 0 then show
end