;+
; Translate galactic coordinates to equatorial coordiantes.
; Currently this only works for B1950 and J2000 coordinates.
;
; @param glon {in}{required}{type=double} Galactic longitude, in degrees.
; @param glat {in}{required}{type=double} Galactic latitude, in degrees.
; @param equinox {in}{required}{type=double} The coordinate system
; EQUINOX in years (must be either 1950.0 or 2000.0). Returns -1 if
; any other value is used.
;
; @returns double precision [ra,dec] in degrees.
;
; @uses <a href="http://idlastro.gsfc.nasa.gov/ftp/pro/astro/glactc.pro">glactc</a>
;
; @version $Id: galtoeq.pro,v 1.5 2005/05/29 17:37:34 bgarwood Exp $
;-
function galtoeq, glon, glat, equinox
   if (equinox eq 1950.0d) then begin
       glactc, ra, dec, equinox, glon, glat, 2, /DEGREE, /FK4
   endif else begin
       if (equinox ne 2000.0d) then begin
           message,'equinox must be 1950.0 or 2000.0',/info
           return, -1
       endif
       glactc, ra, dec, equinox, glon, glat, 2, /DEGREE
   endelse
   return, [ra, dec]
end